home *** CD-ROM | disk | FTP | other *** search
/ Apple II Magazines (DO) / Softdisk Magazette Volume 2, No. 03 (1982-11)(Softdisk)(Side B).zip / Softdisk Magazette Volume 2, No. 03 (1982-11)(Softdisk)(Side B).do / EQUIP LISTER.bas < prev    next >
BASIC Source File  |  1996-12-24  |  2KB  |  71 lines
  1. 1  REM  *GARY ENGLISH
  2. 2  REM  *7100 WEST DUNBAR
  3. 3  REM  *IDA, MICH 48140
  4. 10 D$ =  CHR$(4)
  5. 20  HOME : HTAB 6: INVERSE : PRINT "E Q U I P M E N T  L I S T ": NORMAL : VTAB 2: HTAB 12: PRINT "(PRESS ANY KEY)": GET A$
  6. 30  DIM EQ$(500)
  7. 40  GOTO 130
  8. 50  REM  CHECK PREVIOUS ENTRIES
  9. 60  FOR N = 0 TO I
  10. 70  IF EQ$(N) = EQ$  THEN EQ$ = "":T$ = "ON": GOTO 100
  11. 80  NEXT N
  12. 90  GOTO 110
  13. 100  INVERSE : PRINT "ITEM ALREADY LISTED": NORMAL 
  14. 110  RETURN 
  15. 120  REM  MAIN PROGRAM
  16. 130  HOME : PRINT "IS THERE A LIST ON DISK TO LOAD?(Y/N)": INPUT A$: IF A$ < >"Y"  AND A$ < >"N"  THEN 130
  17. 140  IF A$ = "Y"  THEN  GOSUB 600:J = I: GOTO 160
  18. 150 J = 1
  19. 160  HOME : INVERSE : PRINT "FINISHED";: NORMAL : PRINT "-ALPHABETIZE,PRINT,& SAVE IF DESIRED"
  20. 170  VTAB 2: INVERSE : PRINT "STOP";: NORMAL : PRINT "-ENDS PROGRAM DATA LOST"
  21. 180  VTAB 3: INVERSE : PRINT "SAVE";: NORMAL : PRINT "-SAVE LIST UNDER USER NAME-NOT ALPHABETIZED"
  22. 190  PRINT "----------------------------------------"
  23. 200  POKE 34,5
  24. 210  FOR I = J TO 500
  25. 220  PRINT I;") ";
  26. 230  INPUT "EQUIPMENT ITEM IS: ";EQ$
  27. 240  GOSUB 60
  28. 250  IF T$ = "ON"  THEN T$ = "OFF": GOTO 230
  29. 260  IF EQ$ = "STOP"  THEN  END 
  30. 270  IF EQ$ = "FINISHED"  THEN 320
  31. 280  IF EQ$ = "SAVE"  THEN  GOSUB 490
  32. 290 EQ$(I) = EQ$:EQ$ = ""
  33. 300  NEXT I
  34. 310  REM  ALPHABETIZE
  35. 320 M = 2 ^ INT( LOG(I)/ LOG(2)) -1
  36. 330 N = I -1
  37. 340 M =  INT(M/2): IF M = 0  THEN 410
  38. 350 J = 1:K = N -M
  39. 360 II = J
  40. 370 L = II +M: IF EQ$(II) >EQ$(L)  THEN T$ = EQ$(II):EQ$(II) = EQ$(L):EQ$(L) = T$:II = II -M: IF II >0  THEN 370
  41. 380 J = J +1: IF J >K  THEN 340
  42. 390  GOTO 360
  43. 400  REM  PRINT ROUTINE
  44. 410  INPUT "DO YOU WANT TO SAVE THE LIST? (Y/N)";A2$: IF A2$ < >"Y"  AND A2$ < >"N"  THEN 410
  45. 420  IF A2$ = "Y"  THEN  GOSUB 490
  46. 430  PR# 1
  47. 440  PRINT F$
  48. 450  FOR N = 1 TO I -1
  49. 460  PRINT N;") ";EQ$(N)
  50. 470  NEXT N
  51. 480  PR# 0: END 
  52. 490  INPUT "ENTER A NAME FOR THE LIST";F$
  53. 500  PRINT D$;"OPEN";F$
  54. 510  PRINT D$;"DELETE";F$
  55. 520  PRINT D$;"OPEN";F$
  56. 530  PRINT D$;"WRITE";F$
  57. 540  PRINT I
  58. 550  FOR N = 1 TO I
  59. 560  PRINT EQ$(N)
  60. 570  NEXT N
  61. 580  PRINT D$;"CLOSE";F$
  62. 590  RETURN 
  63. 600  INPUT "WHAT IS THE LIST NAME? ";F$
  64. 610  PRINT D$;"OPEN";F$
  65. 620  PRINT D$;"READ";F$
  66. 630  INPUT I
  67. 640  FOR N = 1 TO I
  68. 650  INPUT EQ$(N)
  69. 660  NEXT N
  70. 670  PRINT D$;"CLOSE";F$
  71. 680  RETURN